|
Atenção. Antes de realizar qualquer envio, por favor siga nossas [Envio de e-mail via hospedagem
|
O componente AspEmail é utilizado para enviar e-mails através de scripts Asp e encontra-se disponível em todos os servidores Windows 2003 e 2008 da Locaweb. Disponibilizamos atualmente o componente AspEmail Premium(FULL), que disponibiliza diversos recursos conforme pode ser consultado nas referências do objeto.
Enviando e-mail com o AspEmail
<%
'Declaramos as váriaveis a serem utilizadas no script
Dim AspEmail, nomeRemetente, emailRemetente, nomeDestinatario, emailDestinatario, emailRetorno, assunto, mensagem, servidor
'Configuramos os dados a serem utilizados no cabeçalho da mensagem
nomeDestinatario="NomeDestinatario"
emailDestinatario="email@dominio"
nomeRemetente="NomeRemetente"
emailRemetente="webmaster@SeuDominio" 'O endereço de e-mail deve ser preenchido com uma conta existente em seu próprio domínio.
emailRetorno="webmaster@SeuDominio"
responderPara="webmaster@SeuDominio"
assunto="Teste AspEmail"
mensagem="Esta é uma mensagem de teste enviada através do componente AspEmail."
servidor="localhost"
'Agora configuramos o componente utilizando os dados informados nas variáveis
'Instancia o objeto na memória
SET AspEmail = Server.CreateObject("Persits.MailSender")
'Contfigura o servidor SMTP a ser utilizado
AspEmail.Host = servidor
'Configura o Nome do remetente da mensagem
AspEmail.FromName = nomeRemetente
'Configura o e-mail do remetente da mensagem que OBRIGATORIAMENTE deve ser um e-mail do seu próprio domínio
AspEmail.From = emailRemetente
'Configura o E-mail de retorno para você ser avisado em caso de problemas no envio da mensagem
AspEmail.MailFrom = emailRemetente 'Desabilitar essa linha caso o servidor esteja configurado para rodar em 64 bits
'Configura o e-mail que receberá as respostas desta mensagem
AspEmail.AddReplyTo responderPara
'Configura os destinatários da mensagem
AspEmail.AddAddress emailDestinatario, nomeDestinatario
'Configura para enviar e-mail Com Cópia
'AspEmail.AddCC "nome0@dominio.com.br", "Nome"
'AspEmail.AddCC "nome1@dominio.com.br", "Nome"
'AspEmail.AddCC "nome2@dominio.com.br", "Nome"
'Configura o Assunto da mensagem enviada
AspEmail.Subject = assunto
'Configura o formato da mensagem para HTML
AspEmail.IsHTML = True
'Configura o conteúdo da Mensagem
AspEmail.Body = mensagem
'Definir porta no caso de envio autenticado
'AspEmail.Port = 587
'Utilize este código caso queira enviar arquivo anexo
'AspEmail.AddAttachment("E:\home\SEU_LOGIN_FTP\Web\caminho_do_arquivo")
'Para quem utiliza serviços da REVENDA conosco
'AspEmail.AddAttachment("E:\vhosts\DOMINIO_COMPLETO\httpdocs\caminho_do_arquivo")
'#Ativa o tratamento de erros
On Error Resume Next
'Envia a mensagem
AspEmail.Send
'Caso ocorra problemas no envio, descreve os detalhes do mesmo.
If Err <> 0 Then
erro = "<b><font color='red'> Erro ao enviar a mensagem.</font></b><br>"
erro = erro & "<b>Erro.Description:</b> " & Err.Description & "<br>"
erro = erro & "<b>Erro.Number:</b> " & Err.Number & "<br>"
erro = erro & "<b>Erro.Source:</b> " & Err.Source & "<br>"
response.write erro
Else
response.write "<font color='blue'><b>Mensagem enviada com sucesso para</b></font> " & emailDestinatario
End If
'## Remove a referência do componente da memória ##
SET AspEmail = Nothing
%> |
Em ambiente WIndows 2008 R2, remova a linha abaixo do código:
AspEmail.MailFrom = emailRemetente 'Desabilitar essa linha caso o servidor esteja configurado para rodar em 64 bits |
|
|
Atenção: O código mencionado acima é somente um exemplo. Caso haja dúvidas quanto sua utilização, sugerimos que verifique juntamente a um desenvolvedor de sua confiança.
|
Consulte o site do desenvolvedor.
Veja também
Links
|
